sll_m_const_coef_advection_2d.F90

Go to the documentation of this file.

 
module sll_m_const_coef_advection_2d
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
#include "sll_memory.h"
#include "sll_working_precision.h"
 
   use sll_m_interpolators_1d_base, only: &
      sll_c_interpolator_1d
 
   use sll_m_operator_splitting, only: &
      sll_s_operator_splitting_init, &
      sll_t_operator_splitting
 
   implicit none
 
   public :: &
      sll_t_const_coef_advection_2d, &
      sll_f_new_const_coef_advection_2d
 
   private
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 
   type, extends(sll_t_operator_splitting) :: sll_t_const_coef_advection_2d
      class(sll_c_interpolator_1d), pointer    :: interp1
      class(sll_c_interpolator_1d), pointer    :: interp2
      sll_real64, dimension(:, :), pointer :: data
      sll_int32 :: n1
      sll_int32 :: n2
      sll_real64 :: a1
      sll_real64 :: a2
   contains
      procedure, pass(this) :: operatort => adv1  
      procedure, pass(this) :: operatorv => adv2  
   end type sll_t_const_coef_advection_2d
 
contains
   function sll_f_new_const_coef_advection_2d(data, n1, n2, a1, a2, interp1, interp2, &
                                              split_case, split_step, nb_split_step, split_begin_T, dt) &
      result(this)
      class(sll_t_const_coef_advection_2d), pointer :: this
      sll_real64, dimension(:, :), pointer, intent(in) :: data   
      sll_int32, intent(in)  :: n1   
      sll_int32, intent(in)  :: n2   
      sll_real64, intent(in) :: a1   
      sll_real64, intent(in) :: a2   
      class(sll_c_interpolator_1d), pointer    :: interp1
      class(sll_c_interpolator_1d), pointer    :: interp2
      sll_int32, intent(in)  :: split_case  
      sll_real64, dimension(:), intent(in), optional :: split_step  
      sll_int32, intent(in), optional :: nb_split_step 
      logical, intent(in), optional :: split_begin_t
      sll_real64, intent(in), optional :: dt  
      ! local variable
      sll_int32 :: ierr
 
      sll_allocate(this, ierr)
      call initialize_const_coef_advection_2d(this, data, n1, n2, a1, a2, interp1, interp2, &
                                              split_case, split_step, nb_split_step, split_begin_t, dt)
 
   end function
 
   subroutine initialize_const_coef_advection_2d(this, data, n1, n2, a1, a2, interp1, interp2, &
                                                 split_case, split_step, nb_split_step, split_begin_T, dt)
      class(sll_t_const_coef_advection_2d), intent(inout)   :: this
      sll_real64, dimension(:, :), pointer, intent(in) :: data   
      sll_int32, intent(in)  :: n1   
      sll_int32, intent(in)  :: n2   
      sll_real64, intent(in) :: a1   
      sll_real64, intent(in) :: a2   
      class(sll_c_interpolator_1d), pointer    :: interp1
      class(sll_c_interpolator_1d), pointer    :: interp2
      sll_int32, intent(in)  :: split_case  
      sll_real64, dimension(:), intent(in), optional :: split_step  
      sll_int32, intent(in), optional :: nb_split_step 
      logical, intent(in), optional :: split_begin_T
      sll_real64, intent(in), optional :: dt  
 
      this%data => data
      this%n1 = n1
      this%n2 = n2
      this%a1 = a1
      this%a2 = a2
      this%interp1 => interp1
      this%interp2 => interp2
 
      call sll_s_operator_splitting_init( &
         this, &
         split_case, &
         split_step, &
         nb_split_step, &
         split_begin_t, &
         dt)
   end subroutine
 
   subroutine adv1(this, dt)
      class(sll_t_const_coef_advection_2d), intent(inout) :: this
      sll_real64, intent(in)                        :: dt   
      ! local variables
      sll_real64, dimension(:), pointer :: f1d
      sll_real64 :: displacement
      sll_int32 :: j
 
      do j = 1, this%n2
         displacement = -this%a1*dt
         f1d => this%data(:, j)
         call this%interp1%interpolate_array_disp_inplace(this%n1, f1d, displacement)
      end do
   end subroutine
 
   subroutine adv2(this, dt)
      class(sll_t_const_coef_advection_2d), intent(inout) :: this
      sll_real64, intent(in)                        :: dt   
      ! local variables
      sll_real64, dimension(:), pointer :: f1d
      sll_real64 :: displacement
      sll_int32 :: i
 
      do i = 1, this%n1
         displacement = -this%a2*dt
         f1d => this%data(i, :)
         call this%interp2%interpolate_array_disp_inplace(this%n2, f1d, displacement)
      end do
   end subroutine
 
end module sll_m_const_coef_advection_2d