sll_m_coordinate_transformation_2d_base.F90

Go to the documentation of this file.

 
module sll_m_coordinate_transformation_2d_base
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
#include "sll_memory.h"
#include "sll_working_precision.h"
 
   use sll_m_cartesian_meshes, only: &
      sll_t_cartesian_mesh_2d
 
   implicit none
 
   public :: &
      sll_c_coordinate_transformation_2d_base, &
      sll_p_io_gmsh, &
      sll_p_io_gnuplot, &
      sll_p_io_mtv, &
      sll_p_io_vtk, &
      sll_p_io_xdmf, &
      sll_i_transformation_func_nopass
 
   private
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 
   sll_int32, parameter ::  sll_p_io_xdmf = 0
   sll_int32, parameter ::  sll_p_io_vtk = 1
   sll_int32, parameter ::  sll_p_io_gnuplot = 2
   sll_int32, parameter ::  sll_p_io_mtv = 3
   sll_int32, parameter ::  sll_p_io_gmsh = 4
 
   type, abstract :: sll_c_coordinate_transformation_2d_base
      type(sll_t_cartesian_mesh_2d), pointer :: mesh => null()
!     type(sll_t_cartesian_mesh_2d), pointer :: mesh2d_minimal => null()
      !logical to remember when the mesh has already been written to file
      character(len=64) :: label
      logical           :: written = .false.
   contains
      procedure(get_cartesian_mesh_ct), deferred, pass        :: get_cartesian_mesh
      procedure(geometry_function_ct), deferred, pass       :: x1
      procedure(geometry_function_ct), deferred, pass       :: x2
      procedure(geometry_function_ct), deferred, pass       :: jacobian
      procedure(geometry_function_indices_ct), deferred, pass :: x1_at_node
      procedure(geometry_function_indices_ct), deferred, pass :: x2_at_node
      procedure(geometry_function_indices_ct), deferred, pass :: jacobian_at_node
      procedure(matrix_geometry_function_ct), deferred, pass   :: jacobian_matrix
      procedure(matrix_geometry_function_ct), deferred, pass :: &
         inverse_jacobian_matrix
      procedure(geometry_function_indices_ct), deferred, pass :: x1_at_cell
      procedure(geometry_function_indices_ct), deferred, pass :: x2_at_cell
      procedure(geometry_function_indices_ct), deferred, pass :: jacobian_at_cell
      procedure(write_transformation_signature), deferred, pass :: write_to_file
      procedure(read_transformation), deferred, pass            :: read_from_file
      procedure(transformation_subroutine), deferred, pass      :: delete
   end type sll_c_coordinate_transformation_2d_base
 
   !************************************************************************
   !
   !                       Function signatures
   !
   !************************************************************************
 
   !************************************************************************
   ! 2D CASE:
   !************************************************************************
 
#ifndef DOXYGEN_SHOULD_SKIP_THIS
 
   abstract interface
      function get_cartesian_mesh_ct(transf) result(res)
         import sll_c_coordinate_transformation_2d_base
         import sll_t_cartesian_mesh_2d
         class(sll_c_coordinate_transformation_2d_base), intent(in) :: transf
         class(sll_t_cartesian_mesh_2d), pointer :: res
      end function get_cartesian_mesh_ct
   end interface
 
   abstract interface
      function geometry_function_ct(transf, eta1, eta2) result(res)
         use sll_m_working_precision
         import sll_c_coordinate_transformation_2d_base
         class(sll_c_coordinate_transformation_2d_base) :: transf
         sll_real64, intent(in)   :: eta1
         sll_real64, intent(in)   :: eta2
         sll_real64               :: res
      end function geometry_function_ct
   end interface
 
   abstract interface
      function geometry_function_indices_ct(transf, i, j) result(res)
         use sll_m_working_precision
         import sll_c_coordinate_transformation_2d_base
         class(sll_c_coordinate_transformation_2d_base) :: transf
         sll_int32, intent(in)   :: i
         sll_int32, intent(in)   :: j
         sll_real64              :: res
      end function geometry_function_indices_ct
   end interface
 
   abstract interface
      function matrix_geometry_function_ct(transf, eta1, eta2)
         use sll_m_working_precision
         import sll_c_coordinate_transformation_2d_base
         class(sll_c_coordinate_transformation_2d_base), intent(inout) :: transf
         sll_real64, intent(in)         :: eta1
         sll_real64, intent(in)         :: eta2
         sll_real64                     :: matrix_geometry_function_ct(2, 2)
      end function matrix_geometry_function_ct
   end interface
 
   ! It is mandatory to pass the params array since making it optional
   ! poses problems when storing the parameters array inside the object to
   ! pass it when the function is called.
   abstract interface
      function sll_i_transformation_func_nopass(eta1, eta2, params) result(res)
         use sll_m_working_precision
         sll_real64, intent(in) :: eta1
         sll_real64, intent(in) :: eta2
         sll_real64, dimension(:), intent(in) :: params
         sll_real64             :: res
      end function sll_i_transformation_func_nopass
   end interface
 
   abstract interface
      function matrix_geometry_function_nopass(eta1, eta2) result(res)
         use sll_m_working_precision
         sll_real64, intent(in) :: eta1
         sll_real64, intent(in) :: eta2
         sll_real64             :: res(2, 2)
      end function matrix_geometry_function_nopass
   end interface
 
   ! WE SHOULD PROBABLY HAVE A SINGLE FILE WITH ALL THE SIGNATURES THAT WE
   ! GENERALLY USE AND DO NOT DEPEND ON A BASE OR DERIVED TYPE.
 
   ! The following interface is meant to specify the signature of the
   ! (possibly user-defined) functions that should be passed as arguments
   ! to initialize the analytic transformations.
   abstract interface
      function two_arg_scalar_function(eta1, eta2)
         use sll_m_working_precision
         sll_real64             :: two_arg_scalar_function
         sll_real64, intent(in) :: eta1
         sll_real64, intent(in) :: eta2
      end function two_arg_scalar_function
   end interface
 
   abstract interface
      function two_arg_message_passing_func(transf, eta1, eta2)
         use sll_m_working_precision
         import     :: sll_c_coordinate_transformation_2d_base
         sll_real64                      :: two_arg_message_passing_func
         class(sll_c_coordinate_transformation_2d_base)  :: transf
         sll_real64, intent(in)          :: eta1
         sll_real64, intent(in)          :: eta2
      end function two_arg_message_passing_func
   end interface
 
   abstract interface
      subroutine write_transformation_signature(transf, output_format)
         use sll_m_working_precision
         import :: sll_c_coordinate_transformation_2d_base
         class(sll_c_coordinate_transformation_2d_base), intent(inout)   :: transf
         sll_int32, intent(in), optional :: output_format
      end subroutine write_transformation_signature
   end interface
 
   abstract interface
      subroutine transformation_subroutine(transf)
         import :: sll_c_coordinate_transformation_2d_base
         class(sll_c_coordinate_transformation_2d_base), intent(inout) :: transf
      end subroutine transformation_subroutine
   end interface
 
   abstract interface
      subroutine read_transformation(transf, filename)
         import :: sll_c_coordinate_transformation_2d_base
         class(sll_c_coordinate_transformation_2d_base), intent(inout) :: transf
         character(len=*), intent(in) :: filename
      end subroutine read_transformation
   end interface
 
#endif /* DOXYGEN_SHOULD_SKIP_THIS */
 
end module sll_m_coordinate_transformation_2d_base