sll_m_finite_difference_interpolator_1d.F90

Go to the documentation of this file.

 
module sll_m_finite_difference_interpolator_1d
#include "sll_working_precision.h"
#include "sll_memory.h"
#include "sll_assert.h"
   use sll_m_interpolators_1d_base
   implicit none
   private
 
   type, extends(sll_c_interpolator_1d) :: sll_finite_difference_interpolator_1d
      sll_int32  :: num_points
      sll_real64 :: delta      ! cell size, distance between data points
      sll_real64 :: r_delta    ! reciprocal of the cell size
   contains
      procedure, pass(interpolator) :: initialize => &
         initialize_finite_difference_1d_interp
      procedure :: compute_interpolants => null_fd_1d_array_msg
      procedure :: interpolate_from_interpolant_value => null_fd_1d_arg_msg
      ! FIXME: define is we want this to explicitly state that we are taking
      ! derivatives with respect to eta or whatnot.
!     procedure :: interpolate_from_interpolant_derivative_eta1 => null_interp_one_arg_msg
      ! yes, we are using the null functions more than once.
      procedure :: interpolate_from_interpolant_derivative_eta1 => null_fd_1d_arg_msg
      procedure :: interpolate_from_interpolant_array => null_fd_1d_array_sub
      procedure :: interpolate_pointer_values => null_fd_1d_ptr_sub
      procedure :: interpolate_from_interpolant_derivatives_eta1 => null_fd_1d_array_sub
      procedure :: interpolate_pointer_derivatives => &
         finite_difference_1d_interp_derivatives
      procedure, pass :: interpolate_array => null_fd_1d_interp_array
      procedure, pass :: reconstruct_array => null_fd_1d_reconstruct
      procedure, pass :: interpolate_array_disp => null_fd_1d_array_disp
   end type sll_finite_difference_interpolator_1d
 
contains
 
   subroutine initialize_finite_difference_1d_interp( &
      interpolator, &
      num_points, &
      delta)
 
      class(sll_finite_difference_interpolator_1d), intent(inout) :: interpolator
      sll_int32, intent(in) :: num_points
      sll_real64, intent(in) :: delta ! cell spacing
      interpolator%num_points = num_points
      interpolator%delta = delta
      interpolator%r_delta = 1.0_f64/delta
   end subroutine initialize_finite_difference_1d_interp
 
   subroutine finite_difference_1d_interp_derivatives( &
      interpolator, &
      num_pts, &
      vals_to_interpolate, &
      output)
 
      class(sll_finite_difference_interpolator_1d), intent(in) :: interpolator
      sll_int32, intent(in) :: num_pts
      ! the following input array must be a pointer so that this function
      ! is usable with splitting methods in higher dimensional data.
      sll_real64, dimension(:), pointer :: vals_to_interpolate
      sll_real64, dimension(:), pointer :: output
      sll_int32  :: i
      sll_real64 :: r_delta
      sll_real64, dimension(:), pointer :: dptr
 
      sll_assert(size(vals_to_interpolate) >= num_pts)
      sll_assert(size(output) >= num_pts)
 
      r_delta = interpolator%r_delta
 
      ! Compute derivative in first point with a forward scheme (-3/2, 2, -1/2)
      output(1) = r_delta*(-1.5_f64*vals_to_interpolate(1) + &
                           2.0_f64*vals_to_interpolate(2) - &
                           0.5_f64*vals_to_interpolate(3))
 
      ! Compute derivative in the bulk of the array with a centered scheme.
      do i = 2, num_pts - 1
         output(i) = 0.5_f64*r_delta*(vals_to_interpolate(i + 1) - &
                                      vals_to_interpolate(i - 1))
      end do
 
      ! Compute derivative in the last point with a backward scheme (1/2, -2, 3/2)
      output(num_pts) = r_delta*(0.5_f64*vals_to_interpolate(num_pts - 2) - &
                                 2.0_f64*vals_to_interpolate(num_pts - 1) + &
                                 1.5_f64*vals_to_interpolate(num_pts))
 
   end subroutine finite_difference_1d_interp_derivatives
 
   ! Define the functions that are not needed in this particular interpolator
   ! with the use of the null-function build macros.
 
   define_null_interp_one_arg_msg(sll_finite_difference_interpolator_1d, null_fd_1d_arg_msg)
 
   define_null_interp_1d_array(sll_finite_difference_interpolator_1d, null_fd_1d_interp_array)
 
   define_null_interp_1d_array_msg(sll_finite_difference_interpolator_1d, null_fd_1d_array_msg)
 
   define_null_interp_1d_array_sub(sll_finite_difference_interpolator_1d, null_fd_1d_array_sub)
 
   define_null_interp_1d_pointer_sub(sll_finite_difference_interpolator_1d, null_fd_1d_ptr_sub)
 
   define_null_reconstruct_1d_array(sll_finite_difference_interpolator_1d, null_fd_1d_reconstruct)
 
   define_null_interpolate_1d_disp(sll_finite_difference_interpolator_1d, null_fd_1d_array_disp)
 
end module sll_m_finite_difference_interpolator_1d