sll_m_linear_operator_GTM.F90

Go to the documentation of this file.

module sll_m_linear_operator_gtm
#include "sll_working_precision.h"
  
  use sll_m_linear_operator_abstract, only : &
       sll_t_linear_operator_abstract
 
  use sll_m_linear_operator_block, only : &
       sll_t_linear_operator_block
 
  use sll_m_spline_fem_utilities, only : &
       sll_s_multiply_gt
 
  implicit none
 
  public :: sll_t_linear_operator_gtm
 
  private
 
  type, extends(sll_t_linear_operator_abstract) :: sll_t_linear_operator_gtm
     type(sll_t_linear_operator_block), pointer :: mass
     sll_int32  :: n_dofs(3)  
     sll_real64 :: delta_x(3) 
     sll_int32  :: n_total 
 
 
   contains
     procedure :: create => create_linear_operator_gtm
     procedure :: free => free_gtm
     procedure :: dot => dot_gtm
     procedure :: print_info => print_info_gtm
 
  end type sll_t_linear_operator_gtm
 
contains
 
 
  subroutine create_linear_operator_gtm( self, mass, n_dofs, delta_x)
    class(sll_t_linear_operator_gtm), intent( inout ) :: self
    type(sll_t_linear_operator_block), target :: mass
    sll_int32                                 :: n_dofs(3) 
    sll_real64                                :: delta_x(3) 
 
    self%mass    => mass
    self%n_dofs  = n_dofs
    self%n_total = product(n_dofs)
    self%delta_x = delta_x
 
    self%n_rows  = self%n_total
    self%n_cols  = 3*self%n_total
 
    self%n_global_rows = self%n_rows
    self%n_global_cols = self%n_cols
  end subroutine create_linear_operator_gtm
 
 
  subroutine free_gtm( self )
    class(sll_t_linear_operator_gtm), intent( inout ) :: self
    self%mass => null()
 
  end subroutine free_gtm
 
 
  subroutine dot_gtm( self, x, y )
    class(sll_t_linear_operator_gtm), intent( in ) :: self
    sll_real64, intent( in    ) :: x(:) 
    sll_real64, intent(   out ) :: y(:) 
    !local variable
    sll_real64 :: scratch(3*self%n_total)
  
    call self%mass%dot(x, scratch)
    call sll_s_multiply_gt(self%n_dofs, self%delta_x, scratch, y)
 
  end subroutine dot_gtm
 
  subroutine print_info_gtm( self )
    class(sll_t_linear_operator_gtm), intent(in) :: self
  end subroutine print_info_gtm
 
 
end module sll_m_linear_operator_gtm