sll_m_linear_operator_poisson_clamped_1d.F90

Go to the documentation of this file.

module sll_m_linear_operator_poisson_clamped_1d
#include "sll_working_precision.h"
  
  use sll_m_linear_operator_abstract, only : &
       sll_t_linear_operator_abstract
 
  use sll_m_matrix_csr, only: &
       sll_t_matrix_csr
 
  use sll_m_spline_fem_utilities_3d_clamped, only: &
       sll_s_multiply_g_clamped_1d, &
       sll_s_multiply_gt_clamped_1d
  
  implicit none
 
  public :: sll_t_linear_operator_poisson_clamped_1d
 
  private
 
  type, extends(sll_t_linear_operator_abstract) :: sll_t_linear_operator_poisson_clamped_1d
     type(sll_t_matrix_csr), pointer :: mass
     sll_int32  :: s_deg_0 
     sll_int32  :: n_dofs  
     sll_real64 :: delta_x 
     
   contains
     procedure :: create     => create_linear_operator_poisson_clamped_1d
     procedure :: free       => free_poisson_clamped_1d
     procedure :: dot        => dot_poisson_clamped_1d
     procedure :: print_info => print_info_poisson_clamped_1d
 
  end type sll_t_linear_operator_poisson_clamped_1d
 
 
contains
 
 
  subroutine create_linear_operator_poisson_clamped_1d( self, mass, s_deg_0, n_dofs, delta_x)
    class(sll_t_linear_operator_poisson_clamped_1d), intent( inout ) :: self
    type(sll_t_matrix_csr), target   :: mass
    sll_int32, intent(in)  :: s_deg_0 
    sll_int32, intent(in)  :: n_dofs  
    sll_real64, intent(in) :: delta_x 
 
    self%mass    => mass
    self%s_deg_0 = s_deg_0
    self%n_dofs  = n_dofs
    self%delta_x = delta_x
 
    self%n_rows  = self%n_dofs
    self%n_cols  = self%n_dofs
 
    self%n_global_rows = self%n_rows
    self%n_global_cols = self%n_cols
  end subroutine create_linear_operator_poisson_clamped_1d
 
 
  subroutine free_poisson_clamped_1d( self )
    class(sll_t_linear_operator_poisson_clamped_1d), intent( inout ) :: self
    self%mass => null()
 
  end subroutine free_poisson_clamped_1d
 
 
  subroutine dot_poisson_clamped_1d( self, x, y )
    class(sll_t_linear_operator_poisson_clamped_1d), intent( in ) :: self
    sll_real64, intent( in    ) :: x(:) 
    sll_real64, intent(   out ) :: y(:) 
    !local variable
    sll_real64 :: scratch1(self%n_dofs-1), scratch2(self%n_dofs-1)
 
    call sll_s_multiply_g_clamped_1d(self%n_dofs, self%delta_x, self%s_deg_0, x, scratch1)
    call self%mass%dot(scratch1, scratch2)
    call sll_s_multiply_gt_clamped_1d(self%n_dofs, self%delta_x, self%s_deg_0, scratch2, y)
  end subroutine dot_poisson_clamped_1d
 
 
  subroutine print_info_poisson_clamped_1d( self )
    class(sll_t_linear_operator_poisson_clamped_1d), intent(in) :: self
  end subroutine print_info_poisson_clamped_1d
 
end module sll_m_linear_operator_poisson_clamped_1d