sll_m_particle_group_4d.F90

Go to the documentation of this file.

!**************************************************************
!  Copyright INRIA
!  Authors :
!     CALVI project team
!
!  This code SeLaLib (for Semi-Lagrangian-Library)
!  is a parallel library for simulating the plasma turbulence
!  in a tokamak.
!
!  This software is governed by the CeCILL-B license
!  under French law and abiding by the rules of distribution
!  of free software.  You can  use, modify and redistribute
!  the software under the terms of the CeCILL-B license as
!  circulated by CEA, CNRS and INRIA at the following URL
!  "http://www.cecill.info".
!**************************************************************
 
module sll_m_particle_group_4d
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
#include "sll_memory.h"
#include "sll_working_precision.h"
 
   use sll_m_cartesian_meshes, only: &
      sll_t_cartesian_mesh_2d
 
   use sll_m_particle_representations, only: &
      sll_t_particle_4d, &
      sll_t_particle_4d_guard_ptr
 
#ifdef _OPENMP
   use omp_lib, only: &
      omp_get_num_threads, &
      omp_get_thread_num
 
#endif
   implicit none
 
   public :: &
      sll_f_new_particle_4d_group, &
      sll_s_particle_4d_group_init, &
      sll_s_particle_4d_group_free, &
      sll_o_delete, &
      sll_t_particle_group_4d
 
   private
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 
   type :: sll_t_particle_group_4d
      sll_int32  :: number_particles
      sll_int32  :: active_particles
      sll_int32  :: guard_list_size
      ! an array indexed by the thread number, of the number of particles
      ! to post-process after the main loop
      sll_int32, dimension(:), pointer :: num_postprocess_particles
      sll_real64 :: qoverm
      type(sll_t_cartesian_mesh_2d), pointer :: mesh
      type(sll_t_particle_4d), dimension(:), pointer           :: p_list
      type(sll_t_particle_4d_guard_ptr), dimension(:), pointer :: p_guard
   end type sll_t_particle_group_4d
 
   interface sll_o_delete
      module procedure sll_s_particle_4d_group_free
   end interface sll_o_delete
 
contains
 
   subroutine sll_s_particle_4d_group_init( &
      res, &
      num_particles, &
      particle_array_size, &
      guard_list_size, &
      qoverm, &
      mesh)
 
      type(sll_t_particle_group_4d)         :: res
      sll_int32, intent(in)                :: num_particles
      sll_int32, intent(in)                :: particle_array_size
      sll_int32, intent(in)                :: guard_list_size
      sll_real64, intent(in)                :: qoverm
      type(sll_t_cartesian_mesh_2d), target :: mesh
 
      sll_int32 :: ierr
      sll_int32 :: n_thread
      sll_int32 :: thread_id
      sll_int32 :: nn
 
      if (num_particles > particle_array_size) then
         print *, 'sll_f_new_particle_4d_group(): ERROR,  num_particles should not ', &
            'be greater than the memory size requested, particle_array_size.'
         stop
      end if
 
      res%number_particles = num_particles
      res%active_particles = num_particles
      res%guard_list_size = guard_list_size
      res%qoverm = qoverm
 
      sll_allocate(res%p_list(particle_array_size), ierr)
 
      n_thread = 1
      thread_id = 0
 
!$omp parallel PRIVATE(thread_id)
#ifdef _OPENMP
      thread_id = omp_get_thread_num()
      if (thread_id == 0) then
         n_thread = omp_get_num_threads()
      end if
#endif
!$omp end parallel
 
      nn = guard_list_size/n_thread
      sll_allocate(res%p_guard(1:n_thread), ierr)
      sll_allocate(res%num_postprocess_particles(1:n_thread), ierr)
 
!$omp parallel PRIVATE(thread_id)
#ifdef _OPENMP
      thread_id = omp_get_thread_num()
#endif
      sll_allocate(res%p_guard(thread_id + 1)%g_list(1:nn), ierr)
!$omp end parallel
 
      res%mesh => mesh
 
   end subroutine sll_s_particle_4d_group_init
 
   function sll_f_new_particle_4d_group( &
      num_particles, &
      particle_array_size, &
      guard_list_size, &
      qoverm, &
      mesh) result(res)
 
      type(sll_t_particle_group_4d), pointer :: res
      sll_int32, intent(in) :: num_particles
      sll_int32, intent(in) :: particle_array_size
      sll_int32, intent(in) :: guard_list_size
      sll_real64, intent(in) :: qoverm
      type(sll_t_cartesian_mesh_2d), pointer :: mesh
      sll_int32 :: ierr
 
      sll_allocate(res, ierr)
 
      call sll_s_particle_4d_group_init( &
         res, &
         num_particles, &
         particle_array_size, &
         guard_list_size, &
         qoverm, &
         mesh)
 
   end function sll_f_new_particle_4d_group
 
   subroutine sll_s_particle_4d_group_free(p_group)
      type(sll_t_particle_group_4d), pointer :: p_group
      sll_int32 :: ierr
      sll_int32 :: thread_id
 
      if (.not. associated(p_group)) then
         print *, 'delete_particle_group_2d(): ERROR, passed group was not ', &
            'associated.'
      end if
 
      thread_id = 0
#ifdef _OPENMP
      thread_id = omp_get_thread_num()
#endif
      sll_deallocate(p_group%num_postprocess_particles, ierr)
      sll_deallocate(p_group%p_guard(thread_id + 1)%g_list, ierr)
      sll_deallocate(p_group%p_list, ierr)
      sll_deallocate(p_group%p_guard, ierr)
      sll_deallocate(p_group, ierr)
   end subroutine sll_s_particle_4d_group_free
 
end module sll_m_particle_group_4d