sll_m_qsort_partition.F90

Go to the documentation of this file.

module sll_m_qsort_partition
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
   implicit none
 
   public :: &
      sll_s_qsortc
 
   private
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 
contains
 
   recursive subroutine sll_s_qsortc(A)
 
      integer, intent(inout), dimension(:) :: a
      integer :: iq
 
      if (size(a) > 1) then
         call partition(a, iq)
         call sll_s_qsortc(a(:iq - 1))
         call sll_s_qsortc(a(iq:))
      end if
 
   end subroutine sll_s_qsortc
 
   subroutine partition(A, marker)
 
      integer, intent(inout), dimension(:) :: A
      integer, intent(out)                 :: marker
      integer                              :: i
      integer                              :: j
      integer                              :: temp
      integer                              :: x
 
      x = a(1)
      i = 0
      j = size(a) + 1
 
      do
         j = j - 1
         do
            if (a(j) <= x) exit
            j = j - 1
         end do
         i = i + 1
         do
            if (a(i) >= x) exit
            i = i + 1
         end do
         if (i < j) then
            ! exchange A(i) and A(j)
            temp = a(i)
            a(i) = a(j)
            a(j) = temp
         elseif (i == j) then
            marker = i + 1
            return
         else
            marker = i
            return
         end if
      end do
 
   end subroutine partition
 
end module sll_m_qsort_partition