sll_m_time_propagator_pic_vm_1d2v_zigsub.F90

Go to the documentation of this file.

 
module sll_m_time_propagator_pic_vm_1d2v_zigsub
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
#include "sll_assert.h"
#include "sll_memory.h"
#include "sll_working_precision.h"
 
  use sll_m_collective, only: &
    sll_o_collective_allreduce, &
    sll_v_world_collective
 
  use sll_m_binomial_filter, only: &
       sll_t_binomial_filter
 
  use sll_m_control_variate, only: &
    sll_t_control_variates
 
  use sll_m_time_propagator_base, only: &
    sll_c_time_propagator_base
 
  use sll_m_particle_mesh_coupling_base_1d, only: &
    sll_c_particle_mesh_coupling_1d
 
  use sll_m_maxwell_1d_base, only: &
    sll_c_maxwell_1d_base
 
  use sll_m_particle_group_base, only: &
    sll_t_particle_array
 
  use mpi, only: &
       mpi_sum
 
  implicit none
 
  public :: &
    sll_s_new_time_propagator_pic_vm_1d2v_zigsub, &
    sll_s_new_time_propagator_pic_vm_1d2v_zigsub_ptr, &
    sll_t_time_propagator_pic_vm_1d2v_zigsub
 
  private
!+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 
  type, extends(sll_c_time_propagator_base) :: sll_t_time_propagator_pic_vm_1d2v_zigsub
     class(sll_c_maxwell_1d_base), pointer :: maxwell_solver
     class(sll_c_particle_mesh_coupling_1d), pointer :: kernel_smoother_0
     class(sll_c_particle_mesh_coupling_1d), pointer :: kernel_smoother_1
     class(sll_t_particle_array), pointer  :: particle_group
 
     sll_int32 :: spline_degree 
     sll_real64 :: lx 
     sll_real64 :: x_min 
     sll_real64 :: delta_x 
 
     sll_real64 :: cell_integrals_0(4) 
     sll_real64 :: cell_integrals_1(3) 
 
 
     sll_real64, pointer     :: efield_dofs(:,:) 
     sll_real64, pointer     :: bfield_dofs(:)   
     sll_real64, allocatable :: j_dofs(:,:)      
     sll_real64, allocatable :: j_dofs_local(:,:)
     sll_int32 :: n_species 
 
     logical :: electrostatic = .false. 
 
     logical :: jmean = .false. 
     sll_real64, allocatable     :: bfield_old(:)   
 
     type(sll_t_binomial_filter), pointer :: filter
 
     ! For version with control variate
     class(sll_t_control_variates), pointer :: control_variate
     sll_int32 :: i_weight 
 
     sll_int32 :: n_sub_iter 
     
   contains
     procedure :: lie_splitting => lie_splitting_pic_vm_1d2v
     procedure :: lie_splitting_back => lie_splitting_back_pic_vm_1d2v
     procedure :: strang_splitting => strang_splitting_pic_vm_1d2v
     procedure :: reinit_fields
 
     procedure :: init => initialize_pic_vm_1d2v
     procedure :: free => delete_pic_vm_1d2v
 
     procedure :: operator_all
 
  end type sll_t_time_propagator_pic_vm_1d2v_zigsub
 
contains
 
  subroutine reinit_fields( self ) 
    class(sll_t_time_propagator_pic_vm_1d2v_zigsub), intent(inout) :: self
    
  end subroutine reinit_fields
  
  subroutine strang_splitting_pic_vm_1d2v(self,dt, number_steps)
    class(sll_t_time_propagator_pic_vm_1d2v_zigsub), intent(inout) :: self
    sll_real64,                                     intent(in)    :: dt   
    sll_int32,                                      intent(in)    :: number_steps 
    !local variables
    sll_int32 :: i_step
 
    if(self%electrostatic) then
       do i_step = 1, number_steps
          call operator_all(self, dt)
       end do
    else
       do i_step = 1, number_steps
          call operator_all(self, dt)
       end do
    end if
    
  end subroutine strang_splitting_pic_vm_1d2v
 
  subroutine lie_splitting_pic_vm_1d2v(self,dt, number_steps)
    class(sll_t_time_propagator_pic_vm_1d2v_zigsub), intent(inout) :: self
    sll_real64,                                     intent(in)    :: dt   
    sll_int32,                                      intent(in)    :: number_steps 
    !local variables
    sll_int32 :: i_step
    if(self%electrostatic) then
       do i_step = 1, number_steps
          call operator_all(self, dt)
       end do
    else
       do i_step = 1,number_steps
          call operator_all(self, dt)
       end do
    end if
 
 
  end subroutine lie_splitting_pic_vm_1d2v
 
  subroutine lie_splitting_back_pic_vm_1d2v(self,dt, number_steps)
    class(sll_t_time_propagator_pic_vm_1d2v_zigsub), intent(inout) :: self
    sll_real64,                                     intent(in)    :: dt   
    sll_int32,                                      intent(in)    :: number_steps 
    !local variables
    sll_int32 :: i_step
 
    if(self%electrostatic) then
       do i_step = 1, number_steps
          call operator_all(self, dt)
       end do
    else
       do i_step = 1,number_steps
          call operator_all(self, dt)
       end do
    end if
 
  end subroutine lie_splitting_back_pic_vm_1d2v
 
  subroutine operator_all( self, dt )
    class(sll_t_time_propagator_pic_vm_1d2v_zigsub), intent(inout) :: self
    sll_real64,                                     intent(in)    :: dt   
    !local variables
    sll_int32 :: i_sp, i_part
    sll_real64 :: bfield, efield(2)
    sll_real64 :: dtau
    sll_real64 :: qoverm
    sll_real64 :: wi(1), vi(3), xi(3), wp(3), x_new(3)
    sll_int32  :: n_cells, iter
    
    dtau = dt/real(self%n_sub_iter, f64)
    
    n_cells = self%kernel_smoother_0%n_dofs
 
    ! Update bfield
    self%bfield_old = self%bfield_dofs
    call self%maxwell_solver%compute_B_from_E( &
         dt, self%efield_dofs(:,2), self%bfield_dofs)
 
    ! Particle loop with subcycling
    self%j_dofs_local = 0.0_f64
    ! Then update particle position:  X_new = X_old + dt * V
    do i_sp = 1,self%n_species
       qoverm = self%particle_group%group(i_sp)%species%q_over_m();
       do i_part=1,self%particle_group%group(i_sp)%n_particles  
          ! Read out particle position and velocity
          xi = self%particle_group%group(i_sp)%get_x(i_part)
          vi = self%particle_group%group(i_sp)%get_v(i_part)
          
          ! Get charge for accumulation of j
          wi = self%particle_group%group(i_sp)%get_charge(i_part, self%i_weight)
 
          ! First push v_1
          ! Evaluate bfield at particle position (splines of order p)
          call self%kernel_smoother_1%evaluate &
               (xi(1), self%bfield_old, bfield)
          vi(1) = vi(1) + dtau*qoverm*vi(2)*bfield
          ! Evaluate efields at particle position
          call self%kernel_smoother_1%evaluate &
               (xi(1), self%efield_dofs(:,1), efield(1))
          vi(1) = vi(1) + dt* qoverm * efield(1)
          
          call self%kernel_smoother_0%add_charge(xi(1:1), wi(1)*vi(2)*dtau, self%j_dofs_local(:,2)) 
                    
          if (self%particle_group%group(i_sp)%n_weights == 3) then
             ! Update weights if control variate
             wp = self%particle_group%group(i_sp)%get_weights(i_part)          
             wp(3) = self%control_variate%cv(i_sp)%update_df_weight( xi(1:1), vi(1:2), 0.0_f64, wp(1), wp(2))
             call self%particle_group%group(i_sp)%set_weights(i_part, wp)
          
             ! Get charge for accumulation of j
             wi = self%particle_group%group(i_sp)%get_charge(i_part, self%i_weight)
          end if
          
          ! Then update particle position:  X_new = X_old + dt * V
          x_new = xi  + dtau * vi
          
          call self%kernel_smoother_1%add_current_update_v( xi, x_new, wi(1), qoverm, &
               self%bfield_dofs, vi, self%j_dofs_local(:,1))
          ! Accumulate rho for Poisson diagnostics
          !call self%kernel_smoother_0%add_charge( x_new, wi(1), &
          !     self%j_dofs_local(:,2))
          ! Evaluate efields at particle position
          call self%kernel_smoother_0%evaluate &
               (xi(1), self%efield_dofs(:,2), efield(2))
          vi(2) = vi(2) + dt* qoverm * efield(2)
          
          x_new(1) = modulo(x_new(1), self%Lx)
     
          if (self%particle_group%group(i_sp)%n_weights == 3) then
             ! Update weights if control variate
             wp = self%particle_group%group(i_sp)%get_weights(i_part)          
             wp(3) = self%control_variate%cv(i_sp)%update_df_weight( x_new(1:1), vi(1:2), 0.0_f64, wp(1), wp(2))
             call self%particle_group%group(i_sp)%set_weights(i_part, wp)
          end if
 
          do iter = 2, self%n_sub_iter
             xi = x_new
             ! First push v_1
             ! Evaluate bfield at particle position (splines of order p)
             call self%kernel_smoother_1%evaluate &
                  (xi(1), self%bfield_dofs, bfield)
             vi(1) = vi(1) + dtau*qoverm*vi(2)*bfield
          
             call self%kernel_smoother_0%add_charge(xi(1:1), wi(1)*vi(2)*dtau, self%j_dofs_local(:,2)) 
                    
             if (self%particle_group%group(i_sp)%n_weights == 3) then
                ! Update weights if control variate
                wp = self%particle_group%group(i_sp)%get_weights(i_part)          
                wp(3) = self%control_variate%cv(i_sp)%update_df_weight( xi(1:1), vi(1:2), 0.0_f64, wp(1), wp(2))
                call self%particle_group%group(i_sp)%set_weights(i_part, wp)
                
                ! Get charge for accumulation of j
                wi = self%particle_group%group(i_sp)%get_charge(i_part, self%i_weight)
             end if
          
             ! Then update particle position:  X_new = X_old + dt * V
             x_new = xi  + dtau * vi
          
             call self%kernel_smoother_1%add_current_update_v( xi, x_new, wi(1), qoverm, &
                  self%bfield_dofs, vi, self%j_dofs_local(:,1))
             ! Accumulate rho for Poisson diagnostics
             !call self%kernel_smoother_0%add_charge( x_new, wi(1), &
             !     self%j_dofs_local(:,2))        
             x_new(1) = modulo(x_new(1), self%Lx)
             
             if (self%particle_group%group(i_sp)%n_weights == 3) then
                ! Update weights if control variate
                wp = self%particle_group%group(i_sp)%get_weights(i_part)          
                wp(3) = self%control_variate%cv(i_sp)%update_df_weight( x_new(1:1), vi(1:2), 0.0_f64, wp(1), wp(2))
                call self%particle_group%group(i_sp)%set_weights(i_part, wp)
             end if
          end do
 
          call self%particle_group%group(i_sp)%set_x(i_part, x_new)
          call self%particle_group%group(i_sp)%set_v(i_part, vi)
       end do
    end do
 
    ! Update the electric field
    self%j_dofs = 0.0_f64
    ! MPI to sum up contributions from each processor
    call sll_o_collective_allreduce( sll_v_world_collective, self%j_dofs_local(:,1), &
         n_cells, mpi_sum, self%j_dofs(:,1))
    call sll_o_collective_allreduce( sll_v_world_collective, self%j_dofs_local(:,2), &
         n_cells, mpi_sum, self%j_dofs(:,2))
    call self%maxwell_solver%compute_E_from_j(self%j_dofs(:,1), 1, self%efield_dofs(:,1))
    call self%maxwell_solver%compute_E_from_j(self%j_dofs(:,2), 2, self%efield_dofs(:,2))
    call self%maxwell_solver%compute_E_from_B(&
         dt, self%bfield_dofs, self%efield_dofs(:,2))
 
 
  end subroutine operator_all
 
 
 
 !---------------------------------------------------------------------------!
  subroutine initialize_pic_vm_1d2v(&
       self, &
       maxwell_solver, &
       kernel_smoother_0, &
       kernel_smoother_1, &
       particle_group, &
       efield_dofs, &
       bfield_dofs, &
       x_min, &
       Lx, &
       n_sub_iter, &
       filter, &
       jmean, &
       control_variate, &
       i_weight, &
       electrostatic) 
    class(sll_t_time_propagator_pic_vm_1d2v_zigsub), intent(out) :: self
    class(sll_c_maxwell_1d_base), target,          intent(in)  :: maxwell_solver
    class(sll_c_particle_mesh_coupling_1d), target,          intent(in)  :: kernel_smoother_0
    class(sll_c_particle_mesh_coupling_1d), target,          intent(in)  :: kernel_smoother_1
    class(sll_t_particle_array), target,           intent(in)  :: particle_group
    sll_real64, target,                            intent(in)  :: efield_dofs(:,:) 
    sll_real64, target,                            intent(in)  :: bfield_dofs(:) 
    sll_real64,                                     intent(in)  :: x_min 
    sll_real64,                                     intent(in)  :: lx 
    sll_int32,                                     intent(in)  :: n_sub_iter 
    type( sll_t_binomial_filter ), intent( in ), target :: filter
    logical, optional, intent(in) :: jmean
    class(sll_t_control_variates), optional, target, intent(in) :: control_variate
    sll_int32, optional,                            intent(in) :: i_weight 
    logical, optional    :: electrostatic
    !local variables
    sll_int32 :: ierr
 
    if( present(electrostatic) )then
       self%electrostatic = electrostatic
    end if
 
    self%maxwell_solver => maxwell_solver
    self%kernel_smoother_0 => kernel_smoother_0
    self%kernel_smoother_1 => kernel_smoother_1
 
    self%n_species = particle_group%n_species
    
    self%particle_group => particle_group
    self%efield_dofs => efield_dofs
    self%bfield_dofs => bfield_dofs
 
    ! Check that n_dofs is the same for both kernel smoothers.
    sll_assert( self%kernel_smoother_0%n_dofs == self%kernel_smoother_1%n_dofs )
 
    sll_allocate(self%j_dofs(self%kernel_smoother_0%n_dofs,2), ierr)
    sll_allocate(self%j_dofs_local(self%kernel_smoother_0%n_dofs,2), ierr)
    sll_allocate(self%bfield_old(self%kernel_smoother_0%n_dofs), ierr)
 
    self%spline_degree = self%kernel_smoother_0%spline_degree
    self%x_min = x_min
    self%Lx = lx
    self%delta_x = self%Lx/real(self%kernel_smoother_1%n_dofs, f64)
    
    self%cell_integrals_1 = [0.5_f64, 2.0_f64, 0.5_f64]
    self%cell_integrals_1 = self%cell_integrals_1 / 3.0_f64
 
    self%cell_integrals_0 = [1.0_f64,11.0_f64,11.0_f64,1.0_f64]
    self%cell_integrals_0 = self%cell_integrals_0 / 24.0_f64
 
    
    if (present(jmean)) then
       self%jmean = jmean
    end if
 
    self%i_weight = 1
    if (present(i_weight)) self%i_weight = i_weight
    if(present(control_variate)) then
       allocate(self%control_variate )
       allocate(self%control_variate%cv(self%n_species) )
       self%control_variate => control_variate
    end if
 
    self%n_sub_iter = n_sub_iter
    
  end subroutine initialize_pic_vm_1d2v
 
  !---------------------------------------------------------------------------!
  subroutine delete_pic_vm_1d2v(self)
    class(sll_t_time_propagator_pic_vm_1d2v_zigsub), intent( inout ) :: self
 
    deallocate(self%j_dofs)
    deallocate(self%j_dofs_local)
    self%maxwell_solver => null()
    self%kernel_smoother_0 => null()
    self%kernel_smoother_1 => null()
    self%particle_group => null()
    self%efield_dofs => null()
    self%bfield_dofs => null()
 
  end subroutine delete_pic_vm_1d2v
 
 
  !---------------------------------------------------------------------------!
  subroutine sll_s_new_time_propagator_pic_vm_1d2v_zigsub(&
       splitting, &
       maxwell_solver, &
       kernel_smoother_0, &
       kernel_smoother_1, &
       particle_group, &
       efield_dofs, &
       bfield_dofs, &
       x_min, &
       Lx, &
       n_sub_iter, &
       filter, &
       jmean, &
       control_variate, &
       i_weight, &
       electrostatic) 
    class(sll_c_time_propagator_base), allocatable, intent(out) :: splitting
    class(sll_c_maxwell_1d_base), target,                intent(in)  :: maxwell_solver
    class(sll_c_particle_mesh_coupling_1d), target,  intent(in)  :: kernel_smoother_0
    class(sll_c_particle_mesh_coupling_1d), target,  intent(in)  :: kernel_smoother_1
    class(sll_t_particle_array), target,           intent(in)  :: particle_group
    sll_real64, target,                                  intent(in)  :: efield_dofs(:,:) 
    sll_real64, target,                                  intent(in)  :: bfield_dofs(:) 
    sll_real64,                                           intent(in)  :: x_min 
    sll_real64,                                           intent(in)  :: lx 
    sll_int32,                                     intent(in)  :: n_sub_iter 
    type( sll_t_binomial_filter ), intent( in ), target :: filter
    logical, optional, intent(in) :: jmean
    class(sll_t_control_variates), optional, target, intent(in) :: control_variate
    sll_int32, optional,                            intent(in) :: i_weight 
    logical, optional    :: electrostatic
    !local variables
    sll_int32 :: ierr
    logical :: jmean_val 
 
    sll_allocate(sll_t_time_propagator_pic_vm_1d2v_zigsub :: splitting, ierr)
 
    if (present(jmean) ) then
       jmean_val = jmean
    else
       jmean_val = .false.
    end if
    
    select type (splitting)
    type is ( sll_t_time_propagator_pic_vm_1d2v_zigsub )
       if (present(control_variate) ) then
          call splitting%init(&
               maxwell_solver, &
               kernel_smoother_0, &
               kernel_smoother_1, &
               particle_group, &
               efield_dofs, &
               bfield_dofs, &
               x_min, &
               lx, &
               n_sub_iter, &
               filter, &
               jmean_val, &
               control_variate, &
               i_weight, &
               electrostatic=electrostatic)
       else
          call splitting%init(&
               maxwell_solver, &
               kernel_smoother_0, &
               kernel_smoother_1, &
               particle_group, &
               efield_dofs, &
               bfield_dofs, &
               x_min, &
               lx, &
               n_sub_iter, &
               filter, &
               jmean_val, &
               electrostatic=electrostatic)
       end if
    end select
 
  end subroutine sll_s_new_time_propagator_pic_vm_1d2v_zigsub
 
  !---------------------------------------------------------------------------!
  subroutine sll_s_new_time_propagator_pic_vm_1d2v_zigsub_ptr(&
       splitting, &
       maxwell_solver, &
       kernel_smoother_0, &
       kernel_smoother_1, &
       particle_group, &
       efield_dofs, &
       bfield_dofs, &
       x_min, &
       Lx, &
       n_sub_iter, &
       filter, &
       jmean, &
       electrostatic) 
    class(sll_c_time_propagator_base), pointer, intent(out) :: splitting
    class(sll_c_maxwell_1d_base), target,            intent(in)  :: maxwell_solver
    class(sll_c_particle_mesh_coupling_1d), target,            intent(in)  :: kernel_smoother_0
    class(sll_c_particle_mesh_coupling_1d), target,            intent(in)  :: kernel_smoother_1
    class(sll_t_particle_array), target,           intent(in)  :: particle_group
    sll_real64, target,                              intent(in)  :: efield_dofs(:,:) 
    sll_real64, target,                              intent(in)  :: bfield_dofs(:) 
    sll_real64,                                       intent(in)  :: x_min 
    sll_real64,                                       intent(in)  :: lx 
    sll_int32,                                     intent(in)  :: n_sub_iter 
    type( sll_t_binomial_filter ), intent( in ), target :: filter
    logical, optional, intent(in) :: jmean
    logical, optional    :: electrostatic
    !local variables
    sll_int32 :: ierr
    logical :: jmean_val
 
    sll_allocate(sll_t_time_propagator_pic_vm_1d2v_zigsub :: splitting, ierr)
 
 
    if (present(jmean) ) then
       jmean_val = jmean
    else
       jmean_val = .false.
    end if
    
    select type (splitting)
    type is ( sll_t_time_propagator_pic_vm_1d2v_zigsub )
       call splitting%init(&
            maxwell_solver, &
            kernel_smoother_0, &
            kernel_smoother_1, &
            particle_group, &
            efield_dofs, &
            bfield_dofs, &
            x_min, &
            lx, &
            n_sub_iter, &
            filter, &
            jmean_val, &
            electrostatic=electrostatic)
    end select
 
  end subroutine sll_s_new_time_propagator_pic_vm_1d2v_zigsub_ptr
 
 
end module sll_m_time_propagator_pic_vm_1d2v_zigsub